home *** CD-ROM | disk | FTP | other *** search
/ Aminet 47 / Aminet 47 (2002)(GTI - Schatztruhe)[Feb 2002].iso / Aminet / game / misc / ETrade.lha / EuroTrade / EuroTrade < prev    next >
Text File  |  2001-11-29  |  20KB  |  822 lines
  1. G4C ;<== Muss in der ersten Zeile stehen!!!
  2.  
  3. ;Schön das Sie sich Mein Werk näher betrachten
  4. ;Diese Programm hatte eine Entwicklungszeit von 4 Wochen
  5. ;
  6. ;$VER: Euro Trade v1.0 (10.08.2001) - ©2001 Nightshade (thenightshade@freenet.de)
  7. ;
  8. ;Dieses Programm wurde mit GoldED 4 PRO, von der "AmigaFuture©20" geschrieben
  9. ;Das Piktogramm von Euro Trade ist von Nightshade, und wurde mit Iconian erstellt
  10. ;Die weiteren Piktogramme sind Default-Icons, die im Gui4Cli-Paket beilagen
  11. ;Die hier verwendeten Fonts sind von der "Amiga plus CD 2/2001"
  12. ;Gui4Cli Version 3.8.5
  13.  
  14. WinBig 0 24 640 53 ""
  15. WinType 00001100
  16. winbackground image winbg 0
  17. screen EUROTRADE
  18. varpath "anzahl"
  19.  
  20. xOnLoad
  21.    ;Ränder setzten
  22.    set tbmargins 5/4       ;ist der Vorgabewert
  23.    set margins 5/0/8       ;Normal ist 5/10/2
  24.  
  25.    ;Laden
  26.    guiopen lade
  27.  
  28.    update lade 1 0
  29.    delay 40
  30.  
  31.    ;Bildschirmtitel
  32.    version   = v1.0
  33.    date      = 10.08.2001
  34.    copyright = ©2001
  35.    name      = Nightshade
  36.    mailme    = thenightshade@freenet.de
  37.    scrtitle  = "Euro Trade $version ($date) - $copyright $name ($mailme) - EmailWare!"
  38.  
  39.    update lade 1 10
  40.    delay 10
  41.  
  42.    ;Zuweisung setzten
  43.    extract #this guipath assignhere
  44.    assign ETrade: $assignhere
  45.  
  46.    update lade 1 15
  47.    delay 10
  48.  
  49.    ;WCP Sounds von der "Amiga plus CD 1/99"
  50.    loadsound ETrade:Sounds/CashRegister.snd nextsnd
  51.    loadsound ETrade:Sounds/ClassicBeep.snd   buysnd
  52.    loadsound ETrade:Sounds/CrashTinkle.snd  quitsnd
  53.    loadsound ETrade:Sounds/ShortBeep.snd    sellsnd
  54.  
  55.    update lade 1 25
  56.    delay 10
  57.  
  58.    ;Gui4Cli Sounds von der "Amiga plus CD 3/2000"
  59.    loadsound ETrade:Samp/Click3    reqsnd
  60.    loadsound ETrade:Samp/Click2 selectsnd
  61.    loadsound ETrade:Samp/Click1  closesnd
  62.    loadsound ETrade:Samp/On       opensnd
  63.    loadsound ETrade:Samp/off      movesnd
  64.  
  65.    update lade 1 50
  66.    delay 10
  67.  
  68.    ;Bilder laden
  69.    ;Die folgenen Bilder wurden von Nightshade erstellt mit
  70.    ;"Personal Paint 6.4" von der "Amiga plus - Cover Disk"
  71.    loadimage ETrade:Bilder/winbg           winbg noremap
  72.    loadimage ETrade:Bilder/winbar           tbar noremap
  73.    loadimage ETrade:Bilder/kaufen1          buy1 noremap
  74.    loadimage ETrade:Bilder/kaufen2          buy2 noremap
  75.    loadimage ETrade:Bilder/verkaufen1      sell1 noremap
  76.    loadimage ETrade:Bilder/verkaufen2      sell2 noremap
  77.    loadimage ETrade:Bilder/weiter1         next1 noremap
  78.    loadimage ETrade:Bilder/weiter2         next2 noremap
  79.    loadimage ETrade:Bilder/ende1           quit1 noremap
  80.    loadimage ETrade:Bilder/ende2           quit2 noremap
  81.    loadimage ETrade:Bilder/kaufen_aus      nobuy noremap
  82.    loadimage ETrade:Bilder/verkaufen_aus  nosell noremap
  83.    loadimage ETrade:Bilder/hiscores1   hiscores1 noremap
  84.    loadimage ETrade:Bilder/hiscores2   hiscores2 noremap
  85.    loadimage ETrade:Bilder/hiscores_aus noscores noremap
  86.  
  87.    update lade 1 100
  88.  
  89.    ;Lade-Fenster schliessen
  90.    delay 100
  91.    guiclose lade
  92.  
  93.    ;Bildschirm initialisieren
  94.    makescreen EUROTRADE 640/77/5/0x29000/newtopaz.font/8 "Euro Trade Screen" ;PAL HighRes Screenmode
  95.    c = 270
  96.    while $c >= 190
  97.       --c
  98.       movescreen #EUROTRADE 0 $c ;Bildschirm nach obenschieben
  99.       playsound movesnd
  100.    endwhile
  101.  
  102.    ;Farbparlette ändern
  103.    palette set winbg EUROTRADE
  104.  
  105.    ;Kopiere HiScores nach T:
  106.    copy ETrade:ETrade.HiScores T:ETrade.temp
  107.  
  108.    ;Fenster öffnen
  109.    guiload ETrade:HiScoreTable
  110.    guiload anzahl
  111.    guiload titlebar
  112.    guiopen titlebar
  113.    GuiOpen #This
  114.    gosub #this go
  115.  
  116. xroutine go
  117.    ;Titel ändern
  118.    setscreentitle #this $scrtitle
  119.  
  120.    ;Intro
  121.    guiwindow #this wait
  122.    guiwindow titlebar wait
  123.       setpointer #this hide
  124.       setpointer titlebar hide
  125.          string = "Herzlich Willkommen bei Euro Trade!"
  126.          delay 50
  127.             update titlebar 1 $string
  128.             redraw titlebar
  129.                gosub #this move in
  130.                delay 200
  131.                   setpointer #this default
  132.                   setpointer titlebar default
  133.                      guiwindow #this resume
  134.                      guiwindow titlebar resume
  135.                         playsound reqsnd
  136.                            gosub #this start_game
  137.                            gosub #this title
  138.  
  139. xroutine start_game
  140.    ;Setze Variablen
  141.    gosub #this set_vars
  142.  
  143.    ;Titel anzeigen
  144.    guiwindow #this wait
  145.    guiwindow titlebar wait
  146.       gosub #this move down
  147.       gosub #this title
  148.       gosub #this move up
  149.    guiwindow #this resume
  150.    guiwindow titlebar resume
  151.  
  152.    ;Kauf/Verkauf
  153.    gosub anzahl check
  154.  
  155.    ;Buttons einstellen
  156.    gosub #this setbutton1
  157.    gosub #this setbutton2
  158.  
  159. xroutine set_vars
  160.    ;Fenster blockieren
  161.    guiwindow #this wait
  162.    guiwindow titlebar wait
  163.  
  164.    ;Levelauswahl
  165.    ezreq "Bitte wählen Sie den Schwierigkeitsgrad:" Leicht|Normal|Schwer level
  166.    playsound selectsnd
  167.    if $level = 1
  168.       maxrunden = 100
  169.    elseif $level = 2
  170.       maxrunden = 75
  171.    elseif $level = 0
  172.       maxrunden = 50
  173.    endif
  174.  
  175.    ;Variabeln setzten
  176.    geld    = 500
  177.    aktien  = 0
  178.    runde   = 0
  179.    kurs    = $($$Rand.998 + 1)
  180.    anzahl  = 1
  181.  
  182.    ;Flash Counter
  183.    counter = 0
  184.  
  185.    ;Fenster befreien
  186.    guiwindow #this resume
  187.    guiwindow titlebar resume
  188.  
  189. xroutine title
  190.    title = "Konto: $geld Euro - Depot: $aktien\% - Runde: $runde\/$maxrunden - Kurs: $kurs Euro"
  191.    update titlebar 1 $title
  192.    redraw titlebar
  193.  
  194. xonRMB
  195.    ;Rechte Maustaste
  196.    guiopen anzahl
  197.  
  198. xonkey #32
  199.    ;Leertaste
  200.    guiopen anzahl
  201.  
  202. xonkey #R
  203.    gosub #this help
  204.  
  205. xroutine help
  206.    if $$RAWKEY.CODE == 80    ;<- Taste F1
  207.       guiwindow #this wait
  208.       guiwindow titlebar wait
  209.          guiscreen #this back
  210.             cli "SYS:Utilities/MultiView ETrade:EuroTrade.Guide"
  211.          guiscreen #this front
  212.       guiwindow #this resume
  213.       guiwindow titlebar resume
  214.    endif
  215.  
  216. xOnClose
  217.    ;Kopiere HiScores nach ETrade:
  218.    copy T:ETrade.temp ETrade:ETrade.HiScores
  219.  
  220.    ;Ordnung muss sein!!!
  221.    delete T:ETrade.temp
  222.  
  223.    ;Titelfenster schliessen
  224.    guiclose titlebar
  225.  
  226.    ;Fenster runterschieben
  227.    c = 190
  228.    while $c <= 270
  229.       ++c
  230.       playsound reqsnd
  231.       movescreen #EUROTRADE 0 $c ;Bildschirm nach untenschieben
  232.    endwhile
  233.  
  234.    ;Bilder freigeben
  235.    freeimage winbg
  236.    freeimage tbar
  237.    freeimage buy1
  238.    freeimage buy2
  239.    freeimage nobuy
  240.    freeimage nosell
  241.    freeimage sell1
  242.    freeimage sell2
  243.    freeimage next1
  244.    freeimage next2
  245.    freeimage quit1
  246.    freeimage quit2
  247.    freeimage hiscores1
  248.    freeimage hiscores2
  249.    freeimage noscores
  250.  
  251.    ;Sounds freigeben
  252.    freesound reqsnd
  253.    freesound selectsnd
  254.    freesound movesnd
  255.    freesound closesnd
  256.    freesound opensnd
  257.    freesound nextsnd
  258.    freesound buysnd
  259.    freesound quitsnd
  260.    freesound sellsnd
  261.  
  262.    ;GUIs Beenden
  263.    guiquit lade
  264.    guiquit anzahl
  265.    guiquit titlebar
  266.    guiquit HiScoreTable
  267.    GuiQuit #This
  268.  
  269.    ;Bildschirm schliessen
  270.    killscreen EUROTRADE
  271.  
  272.    ;Zuweisung entfernen
  273.    assign ETrade: remove
  274.  
  275. ;Image Buttons
  276. image 18 10 nobuy
  277.    ;Kaufen
  278.    gadid 1
  279.  
  280. image 118 10 nosell
  281.    ;Verkaufen
  282.    gadid 2
  283.  
  284. image 455 10 next1
  285.    ;Weiter
  286.    gadid 3
  287.  
  288. image 553 10 quit1
  289.    ;Ende
  290.    gadid 4
  291.  
  292. image 290 10 hiscores1
  293.    ;Hi-Scores
  294.    gadid 5
  295.  
  296. ;HiScore Tabelle Öffnen, und mit Rechter Maustaste schliessen
  297. xarea 296 10 126 32 none
  298.    gadkey h
  299.    ifexists window HiScoreTable
  300.       ;Falls die HiScore Tabelle schon geöffnet ist - Stoppen!!!
  301.       stop
  302.    endif
  303.    playsound reqsnd
  304.    guiwindow #this wait
  305.    guiwindow titlebar wait
  306.    changeimage #this 5 -1 -1 hiscores2
  307.    delay 15
  308.    changeimage #this 5 -1 -1 hiscores1
  309.    delay 15
  310.    guiopen HiScoreTable
  311.  
  312. ;Ändere Kaufen-Button
  313. xroutine setbutton1
  314.    if $betrag <= $geld
  315.    and $($aktien + $anzahl) <= 100
  316.       x = $($geld - $betrag)
  317.       k = 0
  318.       if $x < 0
  319.          x = $($betrag - $geld)
  320.          k = 0
  321.       endif
  322.    else
  323.       k = 1
  324.    endif
  325.  
  326.    if $k = 0
  327.       if $button1 != 0
  328.          button1 = 0
  329.          changeimage #this 1 -1 -1 buy1     ;<= Button ist inkraft
  330.       endif
  331.    else
  332.       if $button1 != 1
  333.          button1 = 1
  334.          changeimage #this 1 -1 -1 nobuy    ;<= Button ist außerkaft
  335.       endif
  336.    endif
  337.  
  338. ;Ändere Verkaufen-Button
  339. xroutine setbutton2
  340.    if $aktien <= 100
  341.    and $aktien >= 0
  342.    and $aktien >= $anzahl
  343.       v = 0
  344.    else
  345.       v = 1
  346.    endif
  347.  
  348.    if $v = 0
  349.       if $button2 != 0
  350.          button2 = 0
  351.          changeimage #this 2 -1 -1 sell1    ;<= Button ist inkraft
  352.       endif
  353.    else
  354.       if $button2 != 1
  355.          button2 = 1
  356.          changeimage #this 2 -1 -1 nosell   ;<= Button ist außerkraft
  357.       endif
  358.    endif
  359.  
  360. ;Zufällige Ereignisse
  361. xroutine random_events
  362.    ifexists variable ~oldev
  363.       oldev = 0
  364.    endif
  365.    gosub #this new_randev
  366.  
  367. xroutine new_randev
  368.    randev = $$RAND.24
  369.    if $randev != $oldev
  370.       oldev = $randev
  371.       gosub #this set_random_events
  372.    else
  373.       gosub #this new_randev
  374.    endif
  375.  
  376. xroutine set_random_events
  377.    docase $randev
  378.      case = 1
  379.             ezreq "Sie haben 50000 Euro geerbt!" "Fein!" ""
  380.             playsound selectsnd
  381.             geld = $($geld + 50000)
  382.             break
  383.      case = 2
  384.             if $($geld - 50000) >= 0
  385.                ezreq "Sie haben sich ein Auto\nfür 50000 Euro gekauft!" "Brum!" ""
  386.                playsound selectsnd
  387.                geld = $($geld - 50000)
  388.             endif
  389.             break
  390.      case = 3
  391.             if $($aktien + 10) <= 100
  392.                ezreq "Durch einen Absturz des Börsen-Computer\nhaben Sie nun 10% Aktien mehr!" "Juppi!" ""
  393.                playsound selectsnd
  394.                aktien = $($aktien + 10)
  395.             endif
  396.             break
  397.      case = 4
  398.             if $($aktien - 10) >= 0
  399.                ezreq "Durch einen Absturz des Börsen-Computer\nhaben Sie nun 10% Aktien weniger!" "Oh, nöh!" ""
  400.                playsound selectsnd
  401.                aktien = $($aktien - 10)
  402.             endif
  403.             break
  404.      case = 5
  405.             ezreq "Sie bekommen 5000 Euro Steuern zurückgezahlt!" "Super!" ""
  406.             playsound selectsnd
  407.             geld = $($geld + 5000)
  408.             break
  409.      case = 6
  410.             if $($geld - 5000) >= 0
  411.                ezreq "Sie müssen 5000 Euro Steuern nachzahlen!" "Mist!" ""
  412.                playsound selectsnd
  413.                geld = $($geld - 5000)
  414.             endif
  415.             break
  416.      case = 7
  417.             if $($geld - 250) >= 0
  418.                ezreq "Beim letzten Aktienkauf wurde\nIhnen 250 Euro zuviel abgebucht!" "Was!" ""
  419.                playsound selectsnd
  420.                geld = $($geld - 250)
  421.             endif
  422.             break
  423.      case = 8
  424.             ezreq "Beim letzten Aktienverkauf wurde\nIhnen 250 Euro zuviel aufgezahlt!" "Stark!" ""
  425.             playsound selectsnd
  426.             geld = $($geld + 250)
  427.             break
  428.      case = 9
  429.             if $($geld - 25000) >= 0
  430.                ezreq "Ihr Fahrer hat bei einer Spritztour einen Unfall gebaut,\nSie müssen 25000 Euro an das Unfallopfer zahlen!" "Au, Backe!" ""
  431.                playsound selectsnd
  432.                geld = $($geld - 25000)
  433.             endif
  434.             break
  435.      case = 10
  436.             ezreq "Beim joggen wurden Sie von einem Auto angefahren,\nSie bekommen 25000 Euro Schadenserzatz!" "Autsch!" ""
  437.             playsound selectsnd
  438.             geld = $($geld + 25000)
  439.             break
  440.      case = 11
  441.             if $($aktien - 25) >= 0
  442.                ezreq "Ihr Börsenmarkler hat 25% Ihres Depots mitgehen lassen!" "Dieser Mistkerl!" ""
  443.                playsound selectsnd
  444.                aktien = $($aktien - 25)
  445.             endif
  446.             break
  447.      case = 12
  448.             if $($aktien + 25) <= 100
  449.                ezreq "Die Polizei hat Ihren Börsenmarkler mit 25% Ihres Depots geschnappt!" "Ab in den Knast mit ihm!" ""
  450.                playsound selectsnd
  451.                aktien = $($aktien + 25)
  452.             endif
  453.             break
  454.    endcase
  455.  
  456. ;Kaufen-Button
  457. xarea 18 10 92 32 none
  458.    gadkey +
  459.    if $button1 = 1
  460.       ;Wenn Button außerkraftgesetzt ist, stoppen
  461.       stop
  462.    endif
  463.    guiwindow #this wait
  464.    guiwindow titlebar wait
  465.    changeimage #this 1 -1 -1 buy2
  466.    playsound buysnd
  467.    delay 15
  468.    changeimage #this 1 -1 -1 buy1
  469.    delay 15
  470.    if $geld >= $kurs
  471.    and $aktien != 100
  472.       menge = $($anzahl * $kurs)
  473.       if $menge <= $geld
  474.          w = $($geld - $menge)
  475.          if $w < 0
  476.            w = $($menge - $geld)
  477.          endif
  478.          geld = $w
  479.       else
  480.          geld = $menge
  481.       endif
  482.       aktien = $($aktien + $anzahl)
  483.       gosub #this title
  484.    endif
  485.    gosub #this setbutton1
  486.    gosub #this setbutton2
  487.    guiwindow #this resume
  488.    guiwindow titlebar resume
  489.  
  490. ;Verkaufen-Button
  491. xarea 118 10 130 32 none
  492.    gadkey -
  493.    if $button2 = 1
  494.       ;Wenn Button außerkraftgesetzt ist, stoppen
  495.       stop
  496.    endif
  497.    guiwindow #this wait
  498.    guiwindow titlebar wait
  499.    changeimage #this 2 -1 -1 sell2
  500.    playsound sellsnd
  501.    delay 15
  502.    changeimage #this 2 -1 -1 sell1
  503.    delay 15
  504.    if $aktien >= 0
  505.       geld = $($geld + ($anzahl * $kurs))
  506.       aktien = $($aktien - $anzahl)
  507.       gosub #this title
  508.    endif
  509.    gosub #this setbutton1
  510.    gosub #this setbutton2
  511.    guiwindow #this resume
  512.    guiwindow titlebar resume
  513.  
  514. ;Weiter-Button
  515. xarea 455 10 90 32 none
  516.    gadkey #13
  517.    guiwindow #this wait
  518.    guiwindow titlebar wait
  519.    changeimage #this 3 -1 -1 next2
  520.    playsound nextsnd
  521.    delay 15
  522.    changeimage #this 3 -1 -1 next1
  523.    delay 15
  524.    ezreq "Wollen Sie diese Runde beenden?" Weiter|Abbrechen weiter
  525.    playsound selectsnd
  526.    guiwindow #this resume
  527.    guiwindow titlebar resume
  528.    if $weiter = 1
  529.       if $geld >= 500000
  530.          guiwindow #this wait
  531.          guiwindow titlebar wait
  532.             while $counter < 10
  533.                flash
  534.                delay 15
  535.                ++counter
  536.             endwhile
  537.             playsound reqsnd
  538.                ezreq "Herzlichen Glückwunsch!\nSie haben in $runde Runden $geld Euro verdient!" Nochmal|ENDE ende
  539.                   guiwindow #this resume
  540.                   guiwindow titlebar resume
  541.                   playsound selectsnd
  542.                      lvuse HiScoreTable 1
  543.                      lvgo last
  544.                      if $geld > $%Geld
  545.                         guiopen Name
  546.                      else
  547.                         gosub #this neues_spiel
  548.                      endif
  549.                   stop
  550.       endif
  551.       if $runde < $maxrunden
  552.          guiwindow #this wait
  553.          guiwindow titlebar wait
  554.             runde = $($runde + 1)
  555.             kurs  = $($$Rand.998 + 1)
  556.             gosub #this random_events
  557.                gosub #this title
  558.                gosub anzahl check
  559.                   gosub #this setbutton1
  560.                   gosub #this setbutton2
  561.                      guiwindow #this resume
  562.                      guiwindow titlebar resume
  563.       else
  564.          guiwindow #this wait
  565.          guiwindow titlebar wait
  566.             ezreq "Das Spiel ist nun zu Ende!\nIch hoffe, es hat Ihnen Spaß gemacht." Neu|Beenden ende
  567.                playsound selectsnd
  568.                   guiwindow #this resume
  569.                   guiwindow titlebar resume
  570.                      gosub #this neues_spiel
  571.       endif
  572.    endif
  573.  
  574. ;Neues Spiel anfangen
  575. xroutine neues_spiel
  576.    if $ende = 1
  577.       gosub #this start_game
  578.       delvar ende
  579.    else
  580.       gosub #this bye
  581.    endif
  582.  
  583. ;Ende-Button
  584. xarea 553 10 70 32 none
  585.    gadkey #27
  586.    guiwindow #this wait
  587.    guiwindow titlebar wait
  588.    changeimage #this 4 -1 -1 quit2
  589.    playsound quitsnd
  590.    delay 15
  591.    changeimage #this 4 -1 -1 quit1
  592.    delay 15
  593.    ezreq 'Wollen Sie \"Euro Trade\" wirklich beenden?' "Ja|Neues Spiel|Nein" quit
  594.    playsound selectsnd
  595.       guiwindow #this resume
  596.       guiwindow titlebar resume
  597.          if $quit = 1
  598.             gosub #this bye
  599.          elseif $quit = 2
  600.             gosub #this start_game
  601.          endif
  602.  
  603. ;Outro
  604. xroutine bye
  605.    guiwindow #this wait
  606.    guiwindow titlebar wait
  607.       setpointer #this hide
  608.       setpointer titlebar hide
  609.          changeimage #this 1 -1 -1 nobuy
  610.          changeimage #this 2 -1 -1 nosell
  611.             gosub #this move down
  612.                update titlebar 1 "Auf Wiedersehen!"
  613.                redraw titlebar
  614.                   gosub #this move up
  615.                   delay 75
  616.                      gosub #this move out
  617.                      delay 20
  618.                         guiwindow #this resume
  619.                         guiwindow titlebar resume
  620.                            setpointer #this default
  621.                            setpointer titlebar default
  622.                               guiclose #this
  623.  
  624. ;Titelzeile scrollen
  625. xroutine move direction
  626.    if $direction = down
  627.       t = 0
  628.       while $t <= 13
  629.          playsound reqsnd
  630.          changegad titlebar 1 0 $t 640 13 ""
  631.          redraw titlebar
  632.          ++t
  633.          delay 2
  634.       endwhile
  635.    elseif $direction = up
  636.       t =  13
  637.       while $t >= 0
  638.          playsound movesnd
  639.          changegad titlebar 1 0 $t 640 13 ""
  640.          redraw titlebar
  641.          --t
  642.          delay 2
  643.       endwhile
  644.    elseif $direction = in
  645.       l = 500
  646.       while $l >= 0
  647.          playsound reqsnd
  648.          changegad titlebar 1 $l 0 640 13 ""
  649.          redraw titlebar
  650.          delay 1
  651.          l = $($l - 2)
  652.       endwhile
  653.    elseif $direction = out
  654.       l = 0
  655.       while $l < 400
  656.          playsound reqsnd
  657.          changegad titlebar 1 $l 0 640 13 ""
  658.          redraw titlebar
  659.          delay 1
  660.          l = $($l + 2)
  661.       endwhile
  662.    endif
  663.  
  664.  
  665. ;xxxxxxxxxxxxxxxxxxxxxxxxxx
  666.       newfile titlebar
  667. ;xxxxxxxxxxxxxxxxxxxxxxxxxx
  668.  
  669.  
  670. winbig 0 11 0 13 ""
  671. wintype 00001100
  672. winbackground image tbar 0
  673. winfont ApplePL.font 8 000
  674. screen EUROTRADE
  675. varpath "EuroTrade"
  676.  
  677. xonopen
  678.    setscreentitle #this $scrtitle
  679.  
  680. xonRMB
  681.    guiopen anzahl
  682.  
  683. xonkey #R
  684.    gosub EuroTrade help
  685.  
  686. xtextbox 640 0 640 13 "" ""
  687.    attr tbstyle 1/28/shadow/center
  688.    attr tbox 2/1/-1/none
  689.       gadid 1
  690.  
  691.  
  692. ;xxxxxxxxxxxxxxxxxxxxxxxxxx
  693.       newfile anzahl
  694. ;xxxxxxxxxxxxxxxxxxxxxxxxxx
  695.  
  696.  
  697. winbig -1 35 300 16 " "
  698. wintype 00000000
  699. winfont ApplePL.font 13 000
  700. screen EUROTRADE
  701. varpath "EuroTrade"
  702.  
  703. xonopen
  704.    attr sound opensnd
  705.    gosub #this changetitle
  706.    delay 10
  707.    setscreentitle #this $scrtitle
  708.    guiwindow EuroTrade wait
  709.    guiwindow titlebar wait
  710.    if $anzahl = 1
  711.    and $id != 1
  712.       id = 1
  713.    endif
  714.    gosub #this set_gads
  715.  
  716. xonclose
  717.    attr sound closesnd
  718.    guiwindow EuroTrade resume
  719.    guiwindow titlebar resume
  720.  
  721. xonrmb
  722.    guiclose #this
  723.  
  724. xonkey #32
  725.    guiclose anzahl
  726.  
  727. xroutine check
  728.    betrag = $($geld - ($geld - ($kurs * $anzahl)))
  729.    gosub #this changetitle
  730.    gosub EuroTrade setbutton1
  731.    gosub EuroTrade setbutton2
  732.  
  733. xroutine changetitle
  734.    setwintitle #this "$anzahl\% á $kurs Euro = $betrag Euro"
  735.  
  736. xroutine set_gads
  737.    ifexists variable old_id
  738.       setgad #this $old_id on
  739.    endif
  740.    setgad #this $id off
  741.    old_id = $id
  742.  
  743. xbutton 0 0 55 0 "+/- 1"
  744. playsound selectsnd
  745. anzahl = 1
  746. id = 1
  747. gosub #this set_gads
  748. gosub #this check
  749. gadkey 1
  750. gadid 1
  751.  
  752. xbutton 55 0 55 0 "+/- 5"
  753. playsound selectsnd
  754. anzahl = 5
  755. id = 2
  756. gosub #this set_gads
  757. gosub #this check
  758. gadkey 2
  759. gadid 2
  760.  
  761. xbutton 110 0 60 0 "+/- 10"
  762. playsound selectsnd
  763. anzahl = 10
  764. id = 3
  765. gosub #this set_gads
  766. gosub #this check
  767. gadkey 3
  768. gadid 3
  769.  
  770. xbutton 170 0 60 0 "+/- 50"
  771. playsound selectsnd
  772. anzahl = 50
  773. id = 4
  774. gosub #this set_gads
  775. gosub #this check
  776. gadkey 4
  777. gadid 4
  778.  
  779. xbutton 230 0 70 0 "+/- 100"
  780. playsound selectsnd
  781. anzahl = 100
  782. id = 5
  783. gosub #this set_gads
  784. gosub #this check
  785. gadkey 5
  786. gadid 5
  787.  
  788.  
  789. ;xxxxxxxxxxxxxxxxxxxxxxxxxx
  790.       newfile lade
  791. ;xxxxxxxxxxxxxxxxxxxxxxxxxx
  792.  
  793.  
  794. winbig -1 -1 300 60 ""
  795. wintype 00001000
  796. winfont Apple.font 22 000
  797. winbackground solid 3 0
  798. screen Workbench
  799.  
  800. xonopen
  801.    guiwindow #this wait
  802.    setpointer #this hide
  803.    
  804.  
  805. xonclose
  806.    guiwindow #this resume
  807.    setpointer #this default
  808.  
  809. xonactive
  810.    setpointer #this hide
  811.  
  812. xoninactive
  813.    setpointer #this default
  814.  
  815. box -1 -1 0 0 out button
  816. box -1 -1 292 56 in icondrop
  817. box -1 31 270 2 out ridge
  818.  
  819. gauge -1 38 250 14 in button 2 3 0
  820. attr title "2/1/shadow/center/above/Lade Euro Trade ..."
  821.    gadid 1
  822.